Personnalisation d’icones

Le samedi 18/08/2012 11:10:46, Milli a écrit dans le message
ce qui suit :
> Bonjour,
>
> j’aimerais remplacer dans mon dossier images les icônes jaunes par d’autres
> icônes. Clic droit sur le dossier/propriétés/personnaliser permet de faire
> cela, mais dossier après dossier. Ayant pas mal de dossier, y’ a t-il un
> moyen d’étendre automatiquement cela à de multiple dossier ?

Pour affecter une icône à un dossier, il suffit de :
1) donner l’attribut R (lecture seule) au dossier
ET
2) créer dans ce dossier un fichier nommé DESKTOP.INI, au format texte,
possédant les attributs caché et système (HS), et contenant le
paragraphe suivant (exemple) :

[.ShellClassInfo]
IconResource=C:\Windows\System32\shell32.dll,241

On peut donc créer un batch qui aura la structure suivante :
on passe en paramètres au batch :
– le nom du dossier auquel on attribue une icône
– le nom du fichier icône
– le n° de l’icône (0 par défaut)

fichier icone.cmd
——– couper ici ——–
@echo off
if %1.==. goto syntaxe
if %2.==. goto syntaxe
if exist %1\nul goto suite1
echo Erreur! Le dossier %1 n’existe pas
goto fin
:suite1
if exist %2 goto suite2
echo Erreur! Le fichier icone %2 n’existe pas
goto fin
:suite2
set num=0
if not %3.==. set num=%3
set desktop=%1\desktop.ini
if exist %desktop% attrib -r -h -s %desktop%
echo [.ShellClassInfo] > %desktop%
echo IconResource=%2,%num% >> %desktop%
attrib +h +s %desktop%
attrib +r %1
echo Fichier %desktop% OK
goto fin
:syntaxe
echo Syntaxe :
echo Icone nom-de-dossier nom-de-fichier-icone [numero icone]
:fin
——– couper ici ——–

Je l’ai évidemment expérimenté : nasodigital !

Exemple :
icone d:\MP3 C:\Windows\System32\shell32.dll 241

Il te reste alors à automatiser cela avec une boucle, ou encore créer
un script maitre qui fera appel en rafale à mon script, bref
l’imagination est au pouvoir !!!!

PS: Pour connaitre les icônes disponibles dans un fichier (EXE, DLL,
…) et leurs n° respectifs, j’ai conçu un script VBS : SELECTICON.VBS

il est dans la section « DIVERS » :

http://www.bellamyjc.fr/technique/vbs-exemples#DIVERS

–

May the Force be with You!
La Connaissance s’accroît quand on la partage
———————————————————-
Jean-Claude BELLAMY [MVP Expert IT Pro]
http://www.bellamyjc.org ou http://jc.bellamy.free.fr