'-- Créer un document XML
Set xmlDoc = CreateObject("Microsoft.XMLDOM")
    
' Créer et ajouter la racine dans le document
' ATTENTION : il ne peut y avoir qu'un seul noeud racine dans un doc XML
Set oRacine = xmlDoc.createElement("Racine")
    
' Ajouter la racine dans le document
xmlDoc.appendChild oRacine

' Ajouter un élément
Set oElement = xmlDoc.selectSingleNode("Racine")  ' positionnement sur la racine
Set oElement = xmlDoc.createElement("element")    ' création d'un fils membre
xmlDoc.documentElement.appendChild oElement       ' crée le fils de la racine

' Ajouter des champs balises
Set oNom = xmlDoc.createElement("nom")
oNom.Text = "LENOM"
oElement.appendChild oNom
Set oNom = Nothing

Set oPrenom = xmlDoc.createElement("prenom")
oPrenom.Text = "Prénom"
oElement.appendChild oPrenom
Set oPrenom = Nothing
Set oElement = Nothing

'-- Indenter le fichier créé
set rdr = CreateObject("MSXML2.SAXXMLReader")
set wrt = CreateObject("MSXML2.MXXMLWriter")
Set oStream = CreateObject("ADODB.STREAM")
oStream.Open 'Ouverture objet stream..
oStream.Charset = "ISO-8859-1"

wrt.indent = True
wrt.encoding = "ISO-8859-1"
wrt.output = oStream ' "Connexion" de l'objet Writer à l'objet Stream
Set rdr.contentHandler = wrt
Set rdr.errorHandler = wrt
rdr.Parse xmlDoc
wrt.flush

' Sauver le fichier créé
oStream.SaveToFile "test1.xml", 2

' Détruire les objets
Set rdr = Nothing
Set wrt = Nothing
Set xmlDoc = Nothing

<?xml version="1.0" encoding="ISO-8859-1" standalone="no"?>
<Racine Create="03/03/2007">
	<element ID="1">
		<nom>LENOM</nom>
		<prenom>Prénom</prenom>
	</element>
</Racine>

'-- Lire un document XML
Set xmlDoc=CreateObject("Microsoft.XMLDOM")

'La desactivation du mode asynchrone permet de charger entièrement le document en mémoire avant le traitement
xmlDoc.Async="false"

'Charger le document en mémoire
xmlDoc.Load("c:\test1.xml")

For each x in xmlDoc.documentElement.childNodes
   Msgbox x.nodename & " : " & x.text
Next
Set xmlDoc = Nothing

'-- Créer un doc XML
Set xmlDoc = CreateObject("Microsoft.XMLDOM")
Set oCreation = xmlDoc.createProcessingInstruction("xml", "version='1.0' encoding='ISO-8859-1'")
xmlDoc.insertBefore oCreation, xmlDoc.childNodes.Item(0)
    
' Créer et ajouter la racine dans le document
' ATTENTION : il ne peut y avoir qu'un seul noeud racine dans un doc XML
Set oRacine = xmlDoc.createElement("Racine")

' Ajouter un attribut Date de création du document
oRacine.setAttribute "Créé_le", FormatDateTime(Date, vbGeneralDate) 
    
' Ajouter la racine dans le document
xmlDoc.appendChild oRacine

' Ajouter un élément
Set oElement = xmlDoc.selectSingleNode("Racine")  ' positionnement sur la racine
Set oElement = xmlDoc.createElement("element")    ' création d'un fils membre

' Ajouter un attribut ID à l'élément créé
oElement.setAttribute "ID", "1"
xmlDoc.documentElement.appendChild oElement       ' crée le fils de la racine

' Ajouter des champs balises
Set oNom = xmlDoc.createElement("nom")
oNom.Text = "LENOM"
oElement.appendChild oNom
Set oNom = Nothing

Set oPrenom = xmlDoc.createElement("prenom")
oPrenom.Text = "Prénom"
oElement.appendChild oPrenom
Set oPrenom = Nothing
Set oElement = Nothing

' Sauver le fichier créé
xmlDoc.save ("test1.xml")
Set xmlDoc = Nothing

<?xml version="1.0" encoding="ISO-8859-1"?>
<Racine Créé_le="19/02/2007">
     <element ID="1">
          <nom>LENOM</nom>
          <prenom>Prénom</prenom>
     </element>
</Racine>

'-- Lire un doc XML
Set xmlDoc=CreateObject("Microsoft.XMLDOM")
xmlDoc.async="false" ' permet de charger entièrement le document en mémoire avant le traitement
xmlDoc.load("test1.xml")

' Lister les valeurs par nom de balise
    Set oElement = xmlDoc.documentElement
        
    If Not oElement Is Nothing Then
        For Each x In oElement.getElementsByTagName("nom")
            MsgBox x.Text
        Next
    End If

'-- Lire un doc XML
Set xmlDoc = CreateObject("Microsoft.XMLDOM")
xmlDoc.async = "false" 
xmlDoc.load("test1.xml")

' Pour tous les noeuds "element", renvoie l'attribut "ID"
' Attention à la casse !
For Each oElement In xmlDoc.getElementsByTagName("element")
      MsgBox oElement.getAttribute("ID")
Next